10 REM gtia mode demo
20 GRAPHICS 0
30 POKE 752,1:POSITION 2,7
40 ? "THIS IS A DEMONSTRATION OF MODES 9-11."
50 ? "TO GO FROM ONE DISPLAY TO THE NEXT, "
60 ? "PRESS THE [start] BUTTON AFTER EACH "
70 ? "DISPLAY IS DONE."
80 ? :? "TO SEE THE LUMINANCES AVAILABLE IN"
90 ? "MODE 9, PRESS [start]. TO CHANGE"
100 ? "THE HUE BASE, PRESS [start] AGAIN..."
110 DEMO=0
120 IF PEEK(53279)=6 THEN 140
130 GOTO 120
140 DEMO=DEMO+1
150 ON DEMO GOSUB 1000,2000,3000,4000,5000,6000,7000,8000,9000,170
160 GOTO 120
170 END 
999 REM 
1000 REM ** MODE 9 LUMINANCES **
1010 GRAPHICS 9
1020 SETCOLOR 4,0,0
1030 FOR H=0 TO 15
1040 COLOR H
1050 FOR P=0 TO 4
1060 PLOT 5*H+P,0:DRAWTO 5*H+P,191
1070 NEXT P:NEXT H
1080 RETURN 
1999 REM 
2000 REM ** CHANGE MODE 9 COLOR BASE
2010 FOR C=1 TO 15
2020 SETCOLOR 4,C,0
2030 FOR T=1 TO 300:NEXT T
2040 NEXT C
2050 RETURN 
3000 GRAPHICS 0:POKE 752,1:POSITION 1,12
3010 ? "THIS IS THE PIXEL SIZE FOR MODES 9-11:":FOR T=1 TO 100:NEXT T
3020 RETURN 
3999 REM 
4000 REM ** GTIA PIXEL SIZE DEMO **
4010 GRAPHICS 11:SETCOLOR 4,0,10
4020 FOR J=1 TO 100
4030 X=INT(80*(RND(0))):Y=INT(192*(RND(0))):C=INT(15*(RND(0)))+1
4040 COLOR C:PLOT X,Y
4050 NEXT J
4060 RETURN 
4070 NEXT X
4080 NEXT Y
4090 RETURN 
4999 REM 
5000 GRAPHICS 0:POKE 752,1:POSITION 2,11
5010 ? "MODE 10 HAS THE SAME PIXEL SIZE, BUT"
5020 ? "CAN SUPPORT UP TO 9 DIFFERENT COLORS"
5030 ? "WITH INDEPENDENT HUES AND LUMINANCES:":FOR T=1 TO 100:NEXT T
5040 RETURN 
5999 REM 
6000 REM ** MODE 10 COLOR DEMO **
6010 GRAPHICS 10
6020 POKE 704,0:POKE 705,30:POKE 706,120:POKE 707,160
6030 SETCOLOR 0,4,4:SETCOLOR 1,3,12:SETCOLOR 2,14,2:SETCOLOR 3,5,12:SETCOLOR 4,1,2
6040 FOR C=1 TO 8
6050 COLOR C
6060 FOR X=0 TO 4
6070 PLOT 10*(C-1)+X,0:DRAWTO 10*(C-1)+X,191
6080 NEXT X
6090 NEXT C
6100 RETURN 
6198 REM 
6199 REM ** MODE 11 COLOR DEMO **
7000 GRAPHICS 0:POKE 752,1:POSITION 2,9
7010 ? "MODE 11 HAS ONLY ONE LUMINANCE, BUT"
7020 ? "CAN SUPPORT 16 DIFFERENT HUES."
7030 ? :? "PRESS [start] TO SEE THE HUES"
7040 ? "AVAILABLE, PRESS [start] AGAIN TO SEE"
7050 ? "THE BASE LUMINANCE CHANGE...":FOR T=1 TO 100:NEXT T
7060 RETURN 
7999 REM 
8000 REM ** MODE 11 HUES **
8010 GRAPHICS 11
8020 SETCOLOR 4,0,0
8030 FOR H=0 TO 15
8040 COLOR H
8050 FOR P=0 TO 4
8060 PLOT 5*H+P,0:DRAWTO 5*H+P,191
8070 NEXT P:NEXT H
8080 RETURN 
8999 REM 
9000 REM ** CHANGE MODE 11 LUMINANCE
9010 FOR L=2 TO 14 STEP 2
9020 SETCOLOR 4,0,L
9030 FOR T=1 TO 200:NEXT T
9040 NEXT L
9050 RETURN 
9999 REM ****************************